接続テストのサンプルプログラム

それでは、app.configファイルの接続文字列を取得して、接続テストをします。フォームにボタンをひとつ追加し、データベースに接続するプログラムを作成します。

最初に、参照の追加で、System.Configurationを追加して、プロジェクトにインポートしてください。

接続ボタンを押すと、データベースの開閉をメッセージボックスに表示します。接続状態は、Stateプロパティを文字列に変換すれば、確認できます。

ConnectionStringSettingsオブジェクトを使用すると、ConfigurationManager クラスのConnectionStrings プロパティで、addタグのname属性を指定すると、アプリケーション構成ファイルから接続文字列を取得できます。

Option Strict On
Imports System.Data.SqlClient
Imports System.Configuration

Public Class Connection

    Private Sub Button1_Click _
    (ByVal sender As System.Object, ByVal e As System.EventArgs) _
    Handles Button1.Click

        Try
            Dim con As New SqlConnection

            Using con
                Dim settings As ConnectionStringSettings

                '接続文字列をapp.configファイルから取得
                settings = _
                ConfigurationManager.ConnectionStrings _
                ("AdoNet.My.MySettings.sampleDBConnectionString")

                If settings Is Nothing Then
                    '接続文字列取得エラー
                    MessageBox.Show("app.configに未登録","接続文字列")

                Else
                    '接続文字列の設定
                    con.ConnectionString = settings.ConnectionString

                    'DBを開く
                    con.Open()

                    '---<< DBの接続状態を確認>>---
                    MessageBox.Show(con.State.ToString, "開いた直後")

                End If

            End Using

            '---<< DBの接続状態を確認>>---
            MessageBox.Show(con.State.ToString, "閉じた直後")

        Catch ex As Exception
            MessageBox.Show(ex.ToString, "接続テストで【例外発生】")

        End Try

    End Sub

End Class